4.5.2 Unione

#include "colors.inc"
camera {
location <0, 1, -10>
look_at 0
angle 36
}

light_source { <500, 500, -1000> White }
plane { y, -1.5
pigment { checker Green White }
}

Aggiungiamo due sfere traslate ciascuna di 0.5 unità sull’asse x nelle direzioni positiva e negativa. Le coloriamo una di blu e l’altra di rosso.

sphere { <0, 0, 0>, 1
pigment { Blue }
translate -0.5*x
}
sphere { <0, 0, 0>, 1
pigment { Red }
translate 0.5*x
}

Renderizziamo questo file a 200x150 -A.

Ora poniamo un blocco union attorno alle due sfere. Questo creerà una singola unione CSG dalle due sfere.

union{
sphere { <0, 0, 0>, 1
pigment { Blue }
translate -0.5*x
}
sphere { <0, 0, 0>, 1
pigment { Red }
translate 0.5*x
}
}

Renderizziamo nuovamente il file.

L'unione non apparirà diversamente da prima, ma ora possiamo assegnare all'intera unione una singola texture e trasformarla come un unico oggetto. Proviamo :

union{
sphere { <0, 0, 0>, 1
translate -0.5*x*
}
sphere { <0, 0, 0>, 1
translate 0.5*x
}
pigment { Red }
scale <1, .25, 1>
rotate <30, 0, 45>
}

Renderizziamo nuovamente il file.

Come possiamo vedere, l'oggetto è estremamente diverso. Sperimentiamo diversi valori di scale e rotate e proviamo qualche texture diversa.
Ci sono molti vantaggi nell'assegnare un'unica texture ad un oggetto CSG invece che assegnare la texture ad ogni componente individuale. Per prima cosa, è molto più semplice usare una sola texture se l'oggetto ha un gran numero di componenti perché se vogliamo cambiare il suo aspetto ci basta modificare una sola frase texture. Secondo, il file viene analizzato più velocemente dal programma dato che la texture viene messa in memoria una volta sola e richiamata dalle componenti dell'oggetto. Assegnare la stessa texture a tutte le n componenti di un oggetto CSG significa metterla in memoria n volte.